arma_3:createurs_de_missions:tips_en_tout_genre:briefing

Ceci est une ancienne révision du document !


Il est possible d'ajouter un briefing directement via un module dans la mission via EDEN… c'est très fortement recommandé. Il est impossible en passant par là de mettre la moindre mise en forme.

La méthode classique est de créer un fichier à la racine de votre mission ( %UserProfile%\Documents\Arma 3\mpmissions\VOTRE_MISSION )

Initialiser le briefing

Il y a 2 actions à faire :

  1. Créer un fichier briefing.sqf
  2. Créer ou modifier le fichier initPlayerLocal.sqf

Vous devez avoir cette ligne dans le fichier, de préférence dans les premières lignes.

execVM "briefing.sqf"; // script qui ajoute le briefing

Pour l'explication, initPlayerLocal.sqf n'est exécuté que chez les joueurs et pas sur le serveur… le serveur n'a pas vraiment besoin d'avoir le briefing ;)

Comment écrire son briefing ?

Le cas classique s'écrit avec cette ligne

player createDiaryRecord ["Diary", ["TITRE", "
    DESCRIPTION DU BRIEFING
"]];

Comment ça fonctionne ?

player

Va impacter le joueur courant, soit le joueur chez qui on exécute le code, et il sera exécuter chez tout le monde, chacun de son côté.

createDiaryRecord 

Est la méthode qui nous permet d'ajouter une note au briefing sur la map, avec l'option “Diary” pour donner le type qu'on veut ajouter

Le titre et la description, c'est à vous de les écrire.

Remarque, le premier que vous notez, sera le dernier de la liste. Inversement le dernier écrit sera le premier dans en jeu !

Exemple de modèle de briefing par Shinriel

player createDiaryRecord ["Diary", ["Credits", "
	Mission faite par Shinriel, 
	<br/>en espérant qu'elle plaise.
"]];

player createDiaryRecord ["Diary", ["Matériel", "
  <font color='#FA5858'>Radios :</font>
  <br/>148 sur squad leader, teams leaders,
  <br/>343 pour tout le monde
  <br/>Voir le roaster pour plus d'informations.

  <br/><br/><font color='#FA5858'>Equipement :</font>

  <br/><br/><font color='#FA5858'>Véhicules :</font>	
"]];

player createDiaryRecord ["Diary", ["Renseignements", "
	<br/><br/><font color='#5858FA'>Intel :</font>

	<br/><br/><font color='#5858FA'>Forces ennemies :</font>

	<br/><br/><font color='#5858FA'>Présence de civil :</font>
"]];

player createDiaryRecord ["Diary", ["Mission", "
	<br/><br/>description courte

	<br/><br/><font color='#5858FA'>Objectifs :</font>

	<br/><br/><font color='#5858FA'>ELement spécifique à la mission :</font>

	<br/><br/>Accomplissement des objectifs à l'appréciation du chef d'opération.
	<br/>Coupure de la mission avec la commande radio 0-0-9 (victoire) ou 0-0-1 (défaite).
"]];
player createDiaryRecord ["Diary", ["Context", "
  Context de la mission, surtout pas la mission à faire, mais ce qu'y se passe avant la mission par exemple.
"]];

Couleur, image, ...

De base le retour à la ligne n'existe pas tel quel dans le briefing, c'est à vous de dire quand vous voulez un retour à la ligne

<br/>

Permet de le faire.

Donc

<br/><br/>

Permet de faire un ligne vide (on revient 2 fois à la ligne)

Dans le même genre on peut ajouter de la couleur

<font color='#5858FA'>Texte en couleur</font>

Qui ajoute la couleur #5858FA. Vous pouvez sélectionner la couleur que vous voulez sur ce site

Pour afficher une image

<img image='images\monter.jpg' width='360' height='280' />

Ici on vient chercher une image qui se trouve dans le dossier de la mission, puis dan sle dossier images, l'image monter.jpg.

width et height sont les tailles en pixel de l'image qu'on veut afficher. Si vous voulez redimensionner votre image, attention à garder ses dimension proportionnel. Merci la règle de 3

Une image de 720x560px, si on veut avoir une largeur max de 360px, =⇒ 360 * 560 / 720 (largeur souhaitée * hauteur d'origine / largeur d'origine) =⇒ 280px

Evitez de faire une taille width supérieur à 360, elle sortirait de la fenêtre de briefing.

Pour une version complète des tags utilisables

Avancé, script et personnalisation

Il est possible de n'afficher un briefing que pour une ou quelques personnes. Le plus simple est d'ajouter un variable name sur une unité ou sur un groupe afin de l'utiliser

player createDiaryRecord ["Diary", ["Tout le monde", "
    blabla
"]];

if(group player == vipTeam) then {
    player createDiaryRecord ["Diary", ["Pour le groupe du vip", "
        blabla
    "]];
};

if(player == vip) then {
    player createDiaryRecord ["Diary", ["Pour le VIP seulement", "
        blabla
    "]];
} else {
    player createDiaryRecord ["Diary", ["Tout le monde sauf le VIP", "
        blabla                
    "]];
};

if(side player == blufor) then {
    player createDiaryRecord ["Diary", ["Seulement pour les blufor", "
        blabla
    "]];
};

Mais il est aussi possible de personnalisé le message en particulier

Avec des conditions et plusieurs textes possible

player createDiaryRecord ["Diary", ["Mission", "
	<br/><br/><font color='#5858FA'>Désamorçage :</font>
	" + 
	(if (params_expert_demo == 0) then {
		"<br/>Tout vos hommes ont été formé pour désamorcer les bombes."
	} else {
		"<br/>Seul les expert en explosifs savent rentrer les codes de désamorçage sur les bombes."
	})
	+ "
	<br />123
"]];

Mais on peut aussi afficher du texte

player createDiaryRecord ["Diary", ["Renseignement", "
  <br />Notre chef " + (name playerLeader) + " connait son métier
"]];
  • arma_3/createurs_de_missions/tips_en_tout_genre/briefing.1566646678.txt.gz
  • Dernière modification: 2019/09/03 21:52
  • (modification externe)